前言

本片博文主要总结 STM32 程序启动流程与启动文件的理解，以及学习过程中的一些体会、遇到的问题，望可以帮助有需要的人。

笔记内容多为自己总结、心得，如有错漏不恰当之处望不吝指正。

一、启动文件概述

启动文件由汇编编写，是系统上电复位后第一个执行的程序。主要做了以下工作：
1、初始化堆栈指针 SP = _initial_sp ；
2、初始化 PC指针 = Reset_Handler ；
3、初始化中断向量表；
4、配置系统时钟；
5、调用 C库函数_main 初始化用户堆栈，从而最终调用 main 函数去到 C的世界；

本文对STM32启动文件 startup_stm32f10x_hd.s 的代码进行分析，其他类型芯片启动文件类似，仅存在些许差异。

二、ARM汇编指令

由于启动文件采用汇编语言编写，分析之前，需要了解一下使用到的汇编指令：
在这里插入图片描述

在这里插入图片描述

二、启动文件代码分析

1.1.Stack(栈)

; <h> Stack Configuration
;   <o> Stack Size (in Bytes) <0x0-0xFFFFFFFF:8>
; </h>

Stack_Size      EQU     0x00000400

                AREA    STACK, NOINIT, READWRITE, ALIGN=3
Stack_Mem       SPACE   Stack_Size
__initial_sp

开辟栈的大小为 0X00000400（1KB），名字为 STACK，NOINIT 即不初始化，可读可写，8（2^3）字节对齐

EQU： 宏定义的伪指令，相当于等于，类似与 C 中的 define。

AREA： 告诉汇编器汇编一个新的代码段或者数据段。STACK 表示段名，这个可以任意命名；NOINIT 表
示不初始化；READWRITE 表示可读可写，ALIGN=3，表示按照 2^3对齐，即 8 字节对齐。

SPACE： 用于分配一定大小的内存空间，单位为字节。这里指定大小等于 Stack_Size。

标号__initial_sp 紧挨着 SPACE 语句放置，表示栈的结束地址，即栈顶地址，栈是由高向低生长的。

2.Heap(堆)

; <h> Heap Configuration
;   <o>  Heap Size (in Bytes) <0x0-0xFFFFFFFF:8>
; </h>

Heap_Size       EQU     0x00000200

                AREA    HEAP, NOINIT, READWRITE, ALIGN=3
__heap_base
Heap_Mem        SPACE   Heap_Size
__heap_limit

                PRESERVE8
                THUMB

开辟堆的大小为 0X00000200（512 字节），名字为 HEAP，NOINIT 即不初始化，可读可写，8（2^3）字节对齐。
__heap_base 表示堆的起始地址；
__heap_limit 表示堆的结束地址；
堆是由低向高生长的，跟栈的生长方向相反。

PRESERVE8 ： 指定当前文件的堆栈按照 8字节对齐；
THUMB ： 表示后面指令兼容 THUMB 指令；

3.Vectors Table (向量表)

; Vector Table Mapped to Address 0 at Reset
                AREA    RESET, DATA, READONLY
                EXPORT  __Vectors
                EXPORT  __Vectors_End
                EXPORT  __Vectors_Size

定义一个数据段，名字为 RESET，只读；
并声明 __Vectors、__Vectors_End 和 __Vectors_Size这三个标号具有全局属性，可供外部的文件调用。
EXPORT ： 声明一个标号可被外部的文件使用，使标号具有全局属性。如果是 IAR 编译器，则使用的是 GLOBAL这个指令。

__Vectors       DCD     __initial_sp               ; Top of Stack
                DCD     Reset_Handler              ; Reset Handler
                ...（省略）
                DCD     SysTick_Handler            ; SysTick Handler

                ; External Interrupts
                DCD     WWDG_IRQHandler            ; Window Watchdog
                ...（省略）
                DCD     DMA2_Channel4_5_IRQHandler ; DMA2 Channel4 & Channel5
__Vectors_End
__Vectors_Size  EQU  __Vectors_End - __Vectors

__Vectors 为向量表起始地址；
__Vectors_End 为向量表结束地址，两个相减即可算出向量表大小；

向量表从 FLASH 的 0x0000 0000地址开始放置，以 4 个字节为一个单位，地址 0x0000 0000存放的是栈顶地址，0X0000 0004 存放的是复位程序的地址，以此类推。从代码上看，向量表中存放的都是中断服务函数的函数名，可我们知道 C 语言中的函数名就是一个地址。

DCD： 分配一个或者多个以字为单位的内存，以四字节对齐，并要求初始化这些内
存。在向量表中，DCD 分配了一堆内存，并且以 ESR 的入口地址初始化它们。

4.ResetHandler (复位中断处理程序)

AREA    |.text|, CODE, READONLY

定义一个名称为.text 的代码段，只读；

; Reset handler
Reset_Handler   PROC
                EXPORT  Reset_Handler             [WEAK]
                IMPORT  __main
                IMPORT  SystemInit
                LDR     R0, =SystemInit
                BLX     R0               
                LDR     R0, =__main
                BX      R0
                ENDP

复位中断程序是系统上电后第一个执行的程序：
首先调用 SystemInit 函数初始化系统时钟；
然后调用 __mian，初始化用户堆栈、拷贝RW Data 从ROM至RAM；
最终调用 main 函数去到 C的世界。

WEAK： 表示弱定义，如果外部文件优先定义了该标号则首先引用该标号，如果外部文件没有声明也不会出错。这里表示复位子程序可以由用户在其他文件重新实现，这里并不是唯一的；

IMPORT： 表示该标号来自外部文件，跟 C 语言中的 EXTERN 关键字类似。这里表示 SystemInit和__main 这两个函数均来自外部的文件；
LDR： 从存储器中加载字到一个寄存器中；

BL： 跳转到由寄存器/标号给出的地址，并把跳转前的下条指令地址保存到 LR；

BLX： 跳转到由寄存器给出的地址，并根据寄存器的 LSE 确定处理器的状态，还要把跳转前的下条指令地址保存到 LR ；

BX： 跳转到由寄存器/标号给出的地址，不用返回；

; Dummy Exception Handlers (infinite loops which can be modified)

NMI_Handler     PROC
                EXPORT  NMI_Handler                [WEAK]
                B       .
                ENDP
HardFault_Handler\
                PROC
                EXPORT  HardFault_Handler          [WEAK]
                B       .
                ENDP
MemManage_Handler\
                PROC
                EXPORT  MemManage_Handler          [WEAK]
                B       .
                ENDP
BusFault_Handler\
                PROC
                EXPORT  BusFault_Handler           [WEAK]
                B       .
                ENDP
UsageFault_Handler\
                PROC
                EXPORT  UsageFault_Handler         [WEAK]
                B       .
                ENDP
SVC_Handler     PROC
                EXPORT  SVC_Handler                [WEAK]
                B       .
                ENDP
DebugMon_Handler\
                PROC
                EXPORT  DebugMon_Handler           [WEAK]
                B       .
                ENDP
PendSV_Handler  PROC
                EXPORT  PendSV_Handler             [WEAK]
                B       .
                ENDP
SysTick_Handler PROC
                EXPORT  SysTick_Handler            [WEAK]
                B       .
                ENDP

Default_Handler PROC

                EXPORT  WWDG_IRQHandler            [WEAK]
                ...（省略）
DMA2_Channel4_5_IRQHandler
                B       .

                ENDP

                ALIGN

启动文件已经帮我们写好所有中断的中断服务函数，跟我们平时写的中断服务函数不一样的就是这些函数都是空的，真正的中断复服务程序需要我们在外部的 C 文件里面重新实现，这里只是提前占了一个位置而已。

如果我们在使用某个外设的时候，开启了某个中断，但是又忘记编写配套的中断服务程序或者函数名写错，那当中断来临的时，程序就会跳转到启动文件预先写好的空的中断服务程序中，并且在这个空函数中无线循环，即程序就死在这里。

B：跳转到一个标号。这里跳转到一个‘.’，即表示无线循环。

5.用户堆栈初始化

;*******************************************************************************
; User Stack and Heap initialization
;*******************************************************************************
                 IF      :DEF:__MICROLIB
                
                 EXPORT  __initial_sp
                 EXPORT  __heap_base
                 EXPORT  __heap_limit
                
                 ELSE
                
                 IMPORT  __use_two_region_memory
                 EXPORT  __user_initial_stackheap
                 
__user_initial_stackheap

                 LDR     R0, =  Heap_Mem
                 LDR     R1, =(Stack_Mem + Stack_Size)
                 LDR     R2, = (Heap_Mem +  Heap_Size)
                 LDR     R3, = Stack_Mem
                 BX      LR

                 ALIGN

                 ENDIF

                 END