最近本来想实现微信小程序通过OneNet平台控制灯开关的，没想到微信小程序代码都写好接口了，才发现onenet想下发命令的应用管理得要钱了，秉承白嫖绝不白给的精神，毅然决然的转用阿里云平台。
文章目录
一、阿里云平台
1.1开通公共实例
不用钱的，一般对于我们这些学生完全够用。
1.2创建产品
点击公共实例进去，然后在设备管理找到产品，点击创建产品进行创建。输入产品名称（由你决定名字），然后选择自定义品类，其他默认即可。
1.3创建设备
在左侧点击设备，进行添加设备，产品选择我们刚刚创建的，设备名字还是由你自己决定！
1.4获取相关的设备数据
在添加设备成功后，在右边点击查看，来到设备详情这里，这里有两处数据需要我们记下，后面用的到，分别是DeviceSecret 三元组数据和MQTT连接参数
1.5创建物模型数据
这里是收集我们上传的数据，在上一步操作的同页面的右边有一个物模型数据，到时候我们的数据是显示在这里的。但是创建这个物模型数据实际是在产品的功能定义那边进行的。
选择自定义功能，不得不说这里的阿里云比Onenet好用的多，这里的标识符与后面传输数据的要一致。数据类型由你决定，我这里是为了让它显示小数点，所以现在float。然后选择发布上线，就如我们在设备页面的物模型数据看到的那样！
二、设备开发
设备我用的是esp32-c3，传感器用的是dht11，代码开发环境是Arduino IDE ,具体工作环境配置可以参考我这篇文章中的开发环境https://blog.csdn.net/weixin_44107116/article/details/122263799?spm=1001.2014.3001.5502。
2.1头文件
#include <WiFi.h>
#include "DHT.h"
#include "PubSubClient.h"
2.2 dht11传感器
#define DHTPIN 7 //数据接口
#define DHTTYPE DHT11 // DHT 11
DHT dht(DHTPIN, DHTTYPE);
2.3 阿里云数据部署
把我们在阿里云获取到的三元组数据和MQTT连接参数换进去
/* 设备的三元组信息*/
#define PRODUCT_KEY "gtbww9C9Wsj"
#define DEVICE_NAME "dht11" //设备名
#define DEVICE_SECRET "54aa54bd68a34c684f15931c643a664e"
#define REGION_ID "cn-shanghai" //看你选择在哪个地方
/* 线上环境域名和端口号，不需要改 */
#define MQTT_SERVER PRODUCT_KEY".iot-as-mqtt."REGION_ID".aliyuncs.com"
#define MQTT_PORT 1883
#define MQTT_USRNAME DEVICE_NAME"&"PRODUCT_KEY
#define CLIENT_ID "gtbww9C9Wsj.dht11|securemode=2,signmethod=hmacsha256,timestamp=2524608000000|"
#define MQTT_PASSWD "2e31a42e357c59e6ca19f6f2b31705c0baddbad8ee4d46118dfecbbe517e70b8"
2.4 MQTT连接服务器
//mqtt连接
void mqttCheckConnect()
{
while (!client.connected())
{
Serial.println("Connecting to MQTT Server ...");
if(client.connect(CLIENT_ID, MQTT_USRNAME, MQTT_PASSWD))
{
Serial.println("MQTT Connected!");
}
else{
Serial.print("MQTT Connect err:");
Serial.println(client.state());
delay(5000);
}
}
}
2.5 发送数据到阿里云
宏定义订阅主题
#define ALINK_BODY_FORMAT "{\"id\":\"dht11\",\"version\":\"1.0\",\"method\":\"thing.event.property.post\",\"params\":%s}" //dht11是设备名，换成你的就可以
#define ALINK_TOPIC_PROP_POST "/sys/" PRODUCT_KEY "/" DEVICE_NAME "/thing/event/property/post"
//发送数据
void mqttIntervalPost()
{
char param[32];
char jsonBuf[128];
soil_data = dht.readHumidity();
sprintf(param, "{\"shidu\":%2f}", soil_data); //换成对应的标识符
sprintf(jsonBuf, ALINK_BODY_FORMAT, param);
Serial.println(jsonBuf);
boolean b = client.publish(ALINK_TOPIC_PROP_POST, jsonBuf);
if(b){
Serial.println("publish Humidity success");
}else{
Serial.println("publish Humidity fail");
}
tep =dht.readTemperature();
sprintf(param, "{\"wendu\":%2f}",tep); //换成对应的标识符
sprintf(jsonBuf, ALINK_BODY_FORMAT, param);
Serial.println(jsonBuf);
boolean c = client.publish(ALINK_TOPIC_PROP_POST, jsonBuf);
if(c){
Serial.println("publish Temperature success");
}else{
Serial.println("publish Temperature fail");
}
}
void setup()
{
Serial.begin(115200);
dht.begin();
wifiInit();
client.setServer(MQTT_SERVER, MQTT_PORT); /* 连接MQTT服务器 */
}
void loop()
{
if (millis() - lastMs >= 5000)
{
lastMs = millis();
mqttCheckConnect();
/* 上报 */
mqttIntervalPost();
}
client.loop();
delay(2000);
}
2.6 完整代码
#include <WiFi.h>
#include "DHT.h"
#include "PubSubClient.h"
#define DHTPIN 7
#define DHTTYPE DHT11 // DHT 11
DHT dht(DHTPIN, DHTTYPE);
/* 连接WIFI SSID和密码 */
#define WIFI_SSID "3671"
#define WIFI_PASSWD "05210835"
/* 设备的三元组信息*/
#define PRODUCT_KEY "gtbww9C9Wsj"
#define DEVICE_NAME "dht11"
#define DEVICE_SECRET "54aa54bd68a34c684f15931c643a664e"
#define REGION_ID "cn-shanghai"
/* 线上环境域名和端口号，不需要改 */
#define MQTT_SERVER PRODUCT_KEY".iot-as-mqtt."REGION_ID".aliyuncs.com"
#define MQTT_PORT 1883
#define MQTT_USRNAME DEVICE_NAME"&"PRODUCT_KEY
#define CLIENT_ID "gtbww9C9Wsj.dht11|securemode=2,signmethod=hmacsha256,timestamp=2524608000000|"
#define MQTT_PASSWD "2e31a42e357c59e6ca19f6f2b31705c0baddbad8ee4d46118dfecbbe517e70b8"
#define ALINK_BODY_FORMAT "{\"id\":\"dht11\",\"version\":\"1.0\",\"method\":\"thing.event.property.post\",\"params\":%s}"
#define ALINK_TOPIC_PROP_POST "/sys/" PRODUCT_KEY "/" DEVICE_NAME "/thing/event/property/post"
unsigned long lastMs = 0;
WiFiClient espClient;
PubSubClient client(espClient);
float soil_data ;
float tep;
//连接wifi
void wifiInit()
{
WiFi.begin(WIFI_SSID, WIFI_PASSWD);
while (WiFi.status() != WL_CONNECTED)
{
delay(1000);
Serial.println("WiFi not Connect");
}
}
//mqtt连接
void mqttCheckConnect()
{
while (!client.connected())
{
Serial.println("Connecting to MQTT Server ...");
if(client.connect(CLIENT_ID, MQTT_USRNAME, MQTT_PASSWD))
{
Serial.println("MQTT Connected!");
}
else{
Serial.print("MQTT Connect err:");
Serial.println(client.state());
delay(5000);
}
}
}
void mqttIntervalPost()
{
char param[32];
char jsonBuf[128];
soil_data = dht.readHumidity();
sprintf(param, "{\"shidu\":%2f}", soil_data);
sprintf(jsonBuf, ALINK_BODY_FORMAT, param);
Serial.println(jsonBuf);
boolean b = client.publish(ALINK_TOPIC_PROP_POST, jsonBuf);
if(b){
Serial.println("publish Humidity success");
}else{
Serial.println("publish Humidity fail");
}
tep =dht.readTemperature();
sprintf(param, "{\"wendu\":%2f}",tep);
sprintf(jsonBuf, ALINK_BODY_FORMAT, param);
Serial.println(jsonBuf);
boolean c = client.publish(ALINK_TOPIC_PROP_POST, jsonBuf);
if(c){
Serial.println("publish Temperature success");
}else{
Serial.println("publish Temperature fail");
}
}
void setup()
{
Serial.begin(115200);
dht.begin();
wifiInit();
client.setServer(MQTT_SERVER, MQTT_PORT); /* 连接MQTT服务器 */
}
void loop()
{
if (millis() - lastMs >= 5000)
{
lastMs = millis();
mqttCheckConnect();
/* 上报 */
mqttIntervalPost();
}
client.loop();
delay(2000);
}
三、遇见的问题
代码没有报错，也成功连接上wifi，但就是连接mqtt服务器连接不上，返错误码是2，后面在网上找到的是：CONNECT指令中需包含KeepAlive（保活时间）。保活心跳时间取值范围为30秒~1200秒。如果心跳时间不在此区间内，物联网平台会拒绝连接。建议取值300秒以上。如果网络不稳定，将心跳时间设置高一些。
后面只要去修改PubSubClient.h文件中定义的 MQTT_MAX_PACKET_SIZE的值， 最好要大于1024， MQTT_KEEPALIVE 大于60；我修改MQTT_KEEPALIVE 这个值即可（代码之前设置的值是5）
四、效果图
新的一年平安喜乐！！！！！