[嵌入式]【花雕动手做】有趣好玩的音乐可视化项目（11）---WS2812幻彩灯带

偶然心血来潮，想要做一个声音可视化的系列专题。这个专题的难度有点高，涉及面也比较广泛，相关的FFT和FHT等算法也相当复杂，不过还是打算从最简单的开始，实际动手做做试验，耐心尝试一下各种方案，逐步积累些有用的音乐频谱可视化的资料，也会争取成型一些实用好玩的音乐可视器项目。

【花雕动手做】有趣好玩的音乐可视化系列小项目（11）—WS2812幻彩LED灯带

WS2812B
是一个集控制电路与发光电路于一体的智能外控LED光源。其外型与一个5050LED灯珠相同，每个元件即为一个像素点。像素点内部包含了智能数字接口数据锁存信号整形放大驱动电路，还包含有高精度的内部振荡器和12V高压可编程定电流控制部分，有效保证了像素点光的颜色高度一致。数据协议采用单线归零码的通讯方式，像素点在上电复位以后，DIN端接受从控制器传输过来的数据，首先送过来的24bit数据被第一个像素点提取后，送到像素点内部的数据锁存器，剩余的数据经过内部整形处理电路整形放大后通过DO端口开始转发输出给下一个级联的像素点，每经过一个像素点的传输，信号减少24bit。像素点采用自动整形转发技术，使得该像素点的级联个数不受信号传送的限制，仅仅受限信号传输速度要求。

主要特点
1、智能反接保护，电源反接不会损坏IC。
2、IC控制电路与LED点光源公用一个电源。
3、控制电路与RGB芯片集成在一个5050封装的元器件中，构成一个完整的外控像素点。
4、内置信号整形电路，任何一个像素点收到信号后经过波形整形再输出，保证线路波形畸变不会累加。
5、内置上电复位和掉电复位电路。
6、每个像素点的三基色颜色可实现256级亮度显示，完成16777216种颜色的全真色彩显示，扫描频率不低于400Hz/s。
7、串行级联接口，能通过一根信号线完成数据的接收与解码。
8、任意两点传传输距离在不超过5米时无需增加任何电路。
9、当刷新速率30帧/秒时，级联数不小于1024点。
10、数据发送速度可达800Kbps。
11、光的颜色高度一致，性价比高。

应用领域
具有低电压驱动，环保节能，亮度高，散射角度大，一致性好，超低功率，超长寿命等优点。将控制电路集成于LED上面，电路变得更加简单，体积小，安装更加简便。主要应用领域，LED全彩发光字灯串，LED全彩模组， LED全彩软灯条硬灯条，LED护栏管。LED点光源，LED像素屏，LED异形屏，各种电子产品，电器设备跑马灯等。

WS2812B灯带电原理图

WS2812B是集控制电路和发光电路于一体的LED光源元件，其控制IC为WS2812B，发光元件是5050RGBLED，电压为5V，每个单位的峰值电流为60ma，灯带为三线制，VCC GND DIN分别为电源+、电源-、信号，当使用外部电源时，外部电源-需要与单片机的GND相连。

MAX9814是一款低成本，高质量的麦克风放大器，具有自动增益控制（AGC）和低噪声麦克风偏置。该器件具有一个低噪声前置放大器，可变增益放大器（VGA），输出放大器，麦克风偏置电压发生器和AGC控制电路。

低噪声前置放大器具有固定的12dB增益，而VGA增益则根据输出电压和AGC阈值自动从20dB调整至0dB。输出放大器提供8dB，18dB和28dB的可选增益。在没有压缩的情况下，放大器的级联会导致总增益为40dB，50dB或60dB。三级数字输入对输出放大器的增益进行编程。外部电阻分压器控制AGC阈值，单个电容器设定启动/释放时间。三级数字输入可设定起效时间与释放时间的比率。AGC的保持时间固定为30ms。低噪声麦克风偏置电压发生器可以使大多数驻极体麦克风偏置。

MAX9814采用节省空间的14引脚TDFN封装。该器件的额定温度范围为-40°C至+ 85°C。

MAX9814麦克风放大器模块
MAX9814是一款低成本高性能麦克风放大器，具有自动增益控制(AGC)和低噪声麦克风偏置。器件具有低噪声前端放大器、可变增益放大(VGA)、输出放大器、麦克风偏置电压发生器和AGC控制电路。
●自动增益控制(AGC)
●3种增益设置(40dB、50dB、60dB)
●可编程动作时间
●可编程动作和释放时间比
●电源电压范围2.7V～5.5V
●低THD：0.04% (典型值)
●低功耗关断模式
●内置2V低噪声麦克风偏置

【花雕动手做】有趣好玩的音乐可视化项目（11）—WS2812幻彩LED灯带
实验程序一：简易测量声级
模块接线：
MAX9814 Arduino
VCC 5V
GND GND
OUT A0

/*
  【花雕动手做】有趣好玩的音乐可视化项目（11）---WS2812幻彩LED灯带
  实验程序一：简易测量声级
  模块接线：
  MAX9814  Arduino
  VCC        5V
  GND        GND
  OUT         A0
*/

const int sampleWindow = 50; // 以mS为单位的采样窗口宽度（50 mS = 20Hz）
unsigned int sample;

void setup() {
  Serial.begin(9600);
  pinMode(A0, INPUT);
}


void loop() {
  unsigned long startMillis = millis(); // 样本窗口的开始
  unsigned int peakToPeak = 0;   // 峰峰值

  unsigned int signalMax = 100;
  unsigned int signalMin = 1024;

  // collect data for 50 mS
  while (millis() - startMillis < sampleWindow)
  {
    sample = analogRead(A0);
    if (sample < 1024)  // 抛出错误的读数
    {
      if (sample > signalMax)
      {
        signalMax = sample;  // 只保存最大级别
      }
      else if (sample < signalMin)
      {
        signalMin = sample;  // 仅保存最低级别
      }
    }
  }
  peakToPeak = signalMax - signalMin;  // max-min =峰峰值幅度
  double volts = (peakToPeak * 5.0) / 256;  // 转换为伏特

  Serial.println(volts);
}

打开Arduino IDE——工具——串口绘图器，查看实验波形

实际测量环境噪音与手敲桌面的声音波形

播放歌曲的实测波形

https://img.mydigit.cn/forum/202207/15/100235ja96zhv6vngh4zow.gif

【花雕动手做】有趣好玩的音乐可视化项目（11）—WS2812幻彩LED灯带
实验程序二：阙值触发的节奏灯

/*
  【花雕动手做】有趣好玩的音乐可视化项目（11）---WS2812幻彩LED灯带
  实验程序二：阙值触发的节奏灯
*/

#include<FastLED.h>
#define LED_PIN 6
#define NUM_LEDS 24

CRGB leds[NUM_LEDS];
uint8_t hue = 0;
int soundsensor = 7;

void setup() {
  delay(2000);
  Serial.begin(9600);
  FastLED.addLeds<WS2812B, LED_PIN, GRB>(leds, NUM_LEDS);
  FastLED.setBrightness(50);
  pinMode(soundsensor, INPUT);
}

void loop() {
  int sensval = digitalRead(soundsensor);

  if (sensval == 1) {
    Serial.println("ON");
    leds[0] = CRGB :: Red;
    fill_solid(leds, NUM_LEDS, CRGB :: Blue);
    rainbow_moving();
    FastLED.show();
    delay(10);
  }
  else {
    leds[0] = CRGB :: Black;
    fill_solid(leds, NUM_LEDS, CRGB :: Black);
    FastLED.show();
    delay(10);
  }
}

void rainbow_moving() {
  for (int i = 0; i < NUM_LEDS; i++) {
    leds[i] = CHSV(hue + (i * 10), 255, 255);
  }
  EVERY_N_MILLISECONDS(10) {
    hue++;
  }
}

实验场景图 动态图

https://img.mydigit.cn/forum/202207/15/112438yztkuu26mtzk2usu.gif

实验的视频记录

https://v.youku.com/v_show/id_XNTg4NjkyODg0OA==.html?spm=a2hcb.playlsit.page.1

【花雕动手做】有趣好玩的音乐可视化项目（11）—WS2812幻彩LED灯带
实验程序三：Adafruit_NeoPixel音乐反应式LED灯带

/*
  【花雕动手做】有趣好玩的音乐可视化项目（11）---WS2812幻彩LED灯带
  实验程序三：Adafruit_NeoPixel音乐反应式LED灯带
*/

#include <Adafruit_NeoPixel.h>
#define MIC A0 // 麦克风与A0相连接
#define LED_PIN 6 // LED are connected to D6
#define N_PIXELS 24 // Number of LED
#define N 100 //样本数
#define fadeDelay 10 // 淡出量
#define noiseLevel 80 // 降噪下限

Adafruit_NeoPixel strip = Adafruit_NeoPixel(N_PIXELS, LED_PIN, NEO_GRB + NEO_KHZ800);

int samples[N]; // 存储样本
int periodFactor = 0; // 用于周期计算
int t1 = -1;
int T;
int slope;
byte periodChanged = 0;

void setup() {
  // Serial.begin(9600);
  strip.begin();
  ledsOff();
  delay(500);
  displayColor(Wheel(100));
  strip.show();
  delay(500);
}

void loop() {
  Samples();
}

void Samples() {
  for (int i = 0; i < N; i++) {
    samples[i] = analogRead(0);
    if (i > 0) {
      slope = samples[i] - samples[i - 1];
    }
    else {
      slope = samples[i] - samples[N - 1];
    }

    if (abs(slope) > noiseLevel) {
      if (slope < 0) {
        calculatePeriod(i);
        if (periodChanged == 1) {
          displayColor(getColor(T));
        }
      }
    }
    else {
      ledsOff();
    }
    periodFactor += 1;
    delay(1);
  }
}

void calculatePeriod(int i) {
  if (t1 == -1) {

    t1 = i;
  }
  else {

    int period = periodFactor * (i - t1);
    periodChanged = T == period ? 0 : 1;
    T = period;
    // Serial.println(T);

    t1 = i;
    periodFactor = 0;
  }
}

uint32_t getColor(int period) {
  if (period == -1)
    return Wheel(0);
  else if (period > 400)
    return Wheel(5);
  else
    return Wheel(map(-1 * period, -400, -1, 50, 255));
}

void fadeOut()
{
  for (int i = 0; i < 5; i++) {
    strip.setBrightness(110 - i * 20);
    strip.show(); // Update strip
    delay(fadeDelay);
    periodFactor += fadeDelay;
  }
}

void fadeIn() {
  strip.setBrightness(100);
  strip.show();

  for (int i = 0; i < 5; i++) {
    //strip.setBrightness(20*i + 30);
    //strip.show();
    delay(fadeDelay);
    periodFactor += fadeDelay;
  }
}

void ledsOff() {
  fadeOut();
  for (int i = 0; i < N_PIXELS; i++) {
    strip.setPixelColor(i, 0, 0, 0);
  }
}

void displayColor(uint32_t color) {
  for (int i = 0; i < N_PIXELS; i++) {
    strip.setPixelColor(i, color);
  }
  fadeIn();
}

uint32_t Wheel(byte WheelPos) {
  // Serial.println(WheelPos);
  if (WheelPos < 85) {

    return strip.Color(WheelPos * 3, 255 - WheelPos * 3, 0);
  }
  else if (WheelPos < 170) {
    WheelPos -= 85;
    return strip.Color(255 - WheelPos * 3, 0, WheelPos * 3);
  }
  else {
    WheelPos -= 170;
    return strip.Color(0, WheelPos * 3, 255 - WheelPos * 3);
  }
}

实验场景图 动态图

https://img.mydigit.cn/forum/202207/15/161443eoa7e1b373x427dh.gif

实验的视频记录（《西部世界》主题曲2分7秒）

https://v.youku.com/v_show/id_XNTg4NzAwNzUwMA==.html?spm=a2hcb.playlsit.page.1

【花雕动手做】有趣好玩的音乐可视化项目（11）—WS2812幻彩LED灯带
实验程序四：MegunoLink音乐反应式24颗LED灯带

/*
  【花雕动手做】有趣好玩的音乐可视化项目（11）---WS2812幻彩LED灯带
  实验程序四：MegunoLink音乐反应式24颗LED灯带
*/

#include<FastLED.h>
#include<MegunoLink.h>
#include<Filter.h>

// define necessary parameters
#define N_PIXELS  24
#define MIC_PIN   A0
#define LED_PIN   D6 // labeled "D6" on the board
// the following parameters can be tweaked according to your audio levels
#define NOISE 50
#define TOP   (N_PIXELS+2) // allow the max level to be slightly off scale
#define LED_TYPE  WS2811
#define BRIGHTNESS  18     // a little dim for recording purposes
#define COLOR_ORDER GRB

// declare the LED array
CRGB leds[N_PIXELS];

// define the variables needed for the audio levels
int lvl = 0, minLvl = 0, maxLvl = 600; // tweak the min and max as needed

// instantiate the filter class for smoothing the raw audio signal
ExponentialFilter<long> ADCFilter(5,0);

void setup() {
  // put your setup code here, to run once:
  Serial.begin(115200);
  // initialize the LED object
  FastLED.addLeds<LED_TYPE,LED_PIN,COLOR_ORDER>(leds,N_PIXELS).setCorrection(TypicalLEDStrip);
  FastLED.setBrightness(BRIGHTNESS);
}

void loop() {
  // put your main code here, to run repeatedly:
  // read the audio signal and filter it
  int n, height;
  n = analogRead(MIC_PIN);
  // remove the MX9614 bias of 1.25VDC
  n = abs(1023 - n);
  // hard limit noise/hum
  n = (n <= NOISE) ? 0 : abs(n - NOISE);
  // apply the exponential filter to smooth the raw signal
  ADCFilter.Filter(n);
  lvl = ADCFilter.Current();
//  // plot the raw versus filtered signals
//  Serial.print(n);
//  Serial.print(" ");
//  Serial.println(lvl);
  // calculate the number of pixels as a percentage of the range
  // TO-DO: can be done dynamically by using a running average of min/max audio levels
  height = TOP * (lvl - minLvl) / (long)(maxLvl - minLvl);
  if(height < 0L) height = 0;
  else if(height > TOP) height = TOP;
  // turn the LEDs corresponding to the level on/off
  for(uint8_t i = 0; i < N_PIXELS; i++) {
    // turn off LEDs above the current level
    if(i >= height) leds[i] = CRGB(0,0,0);
    // otherwise, turn them on!
    else leds[i] = Wheel( map( i, 0, N_PIXELS-1, 30, 150 ) );
  }
  FastLED.show();
}

CRGB Wheel(byte WheelPos) {
  // return a color value based on an input value between 0 and 255
  if(WheelPos < 85)
    return CRGB(WheelPos * 3, 255 - WheelPos * 3, 0);
  else if(WheelPos < 170) {
    WheelPos -= 85;
    return CRGB(255 - WheelPos * 3, 0, WheelPos * 3);
  } else {
    WheelPos -= 170;
    return CRGB(0, WheelPos * 3, 255 - WheelPos * 3);
  }
}

实验场景图 动态图

https://img.mydigit.cn/forum/202207/20/145720agtd6fhv676dazhe.gif

实验的视频记录

https://v.youku.com/v_show/id_XNTg4NzE0NDMxNg==.html?spm=a2hcb.playlsit.page.1