为了从开源代码生成第三方库，需要复制相关的头文件（.h文件）、静态库文件（.lib文件）、动态库文件（.dll文件）、以及与库文件同名的pdb文件。如果只需要生成一两个库文件，人工做还好；如果有十几甚至几十个库，人手工复制文件是一件很令人抓狂的事情。
本文使用批处理文件来解决这个问题，使用计算机完成这种简单的重复性工作。
以Zlib的源码编译为例，使用CMake、VS2019生成Debug及Release版本，在Debug的目录中有以下文件：
?
需求是：将目录“D:\SourceCodes\zlib-1.2.11\build\Debug”中的zlibd.lib、zlibd.pdb、zlibstaticd.lib、zlibstaticd.pdb四个文件复制到目录“D:\My3rdParty\lib”中；将zlibd.lib、zlibd.pdb两个文件复制到目录“D:\My3rdParty\bin”中；将“D:\SourceCodes\zlib-1.2.11”及“D:\SourceCodes\zlib-1.2.11\build”两个目录中的所有头文件复制到目录“D:\My3rdParty\include”中。
以上这些工作，人工可以做，但是项目多时，人工做的效率低，还很容易出错，所以编写批处理文件来做，好处是大大的。
批处理文件名为makeMy3rdParty（假设该文件在目录“D:\My3rdParty”中）内容如下：
@echo off
setlocal ENABLEDELAYEDEXPANSION ENABLEEXTENSIONS
rem 来源目录
set srcDir=%1
echo srcDir is %srcDir%
rem 目标目录
set dstDir=%2
echo dstDir is %dstDir%
rem debug版lib文件所在目录及目标目录
set src=%srcDir%\build\debug
set dst=%dstDir%\lib
rem 复制lib及pdb文件到lib目录
for /r %src% %%i in (*.lib) do (
rem 复制lib文件
echo copying %%i to %dst%
copy %%i %dst%
rem 复制同名的pdb文件
echo copying %src%\%%~ni.pdb to %dst%
copy %src%\%%~ni.pdb %dst%
)
rem 复制dll及pdb文件到bin目录
set src=%srcDir%\build\debug
set dst=%dstDir%\bin
rem 复制lib及pdb文件到lib目录
for /r %src% %%i in (*.dll) do (
rem 复制lib文件
echo copying %%i to %dst%
copy %%i %dst%
rem 复制同名的pdb文件
echo copying %src%\%%~ni.pdb to %dst%
copy %src%\%%~ni.pdb %dst%
)
rem 复制release版lib文件
echo copying release lib files
set src=%srcDir%\build\release
set dst=%dstDir%\lib
echo copying %src%\*.lib to %dst%
copy %src%\*.lib %dst%
rem 复制release版dll文件
echo copying release dll files
set src=%srcDir%\build\release
set dst=%dstDir%\bin
echo copying %src%\*.dll to %dst%
copy %src%\*.dll %dst%
rem 复制头文件
echo copying header files to %dstDir%\include
copy %srcDir%\*.h %dstDir%\include
copy %srcDir%\build\*.h %dstDir%\include
其中for语句参考了网页 批处理命令 For循环命令详解! - 疯狂的tiger - 博客园?
在cmd窗口的命令行输入命令：
D:\My3rdParty\makeMy3rdParty D:\SourceCodes\zlib-1.2.11 D:\My3rdParty
运行结果如下所示。
?