[游戏开发]UVM实战 卷I学习笔记5——UVM基础（4）UVM中打印信息的控制

设置打印信息的冗余度阈值

UVM通过冗余度级别的设置提高了仿真日志的可读性。在打印信息之前，UVM会比较要显示信息的冗余度级别与默认的冗余度阈值，如果小于等于阈值就会显示，否则不会显示。默认的冗余度阈值是UVM_MEDIUM，所有低于等于UVM_MEDIUM（如UVM_LOW）的信息都会被打印出来。

可通过get_report_verbosity_level函数得到某个component的冗余度阈值：

virtual function void connect_phase(uvm_phase phase);
	$display("env.i_agt.drv's verbosity level is %0d", env.i_agt.drv.get_report_verbosity_level());
endfunction

这个函数得到的是一个整数，它代表的含义如下所示：

typedef enum
{
	UVM_NONE = 0,
	UVM_LOW = 100,
	UVM_MEDIUM = 200,
	UVM_HIGH = 300,
	UVM_FULL = 400,
	UVM_DEBUG = 500
} uvm_verbosity;

UVM提供set_report_verbosity_level函数设置某个特定component的默认冗余度阈值。在base_test中将driver冗余度阈值设为UVM_HIGH（UVM_LOW、UVM_MEDIUM、UVM_HIGH的信息都会被打印）代码为：

 virtual function void connect_phase(uvm_phase phase);
	env.i_agt.drv.set_report_verbosity_level(UVM_HIGH);
	…
endfunction

注意：由于需要牵扯到层次引用，所以需要在connect_phase及以后的phase才能调用这个函数。如果不牵扯到任何层次引用，如设置当前component的冗余度阈值，那么可以在connect_phase之前调用。

set_report_verbosity_level只对某个特定的component起作用。UVM同样提供递归的设置函数set_report_verbosity_level_hier，如把env.i_agt及其下所有component的冗余度阈值设置为UVM_HIGH的代码为：env.i_agt.set_report_verbosity_level_hier(UVM_HIGH);

`uvm_info("ID1", "ID1 INFO", UVM_HIGH)
`uvm_info("ID2", "ID2 INFO", UVM_HIGH)

可使用set_report_id_verbosity函数来区分不同ID的冗余度阈值：env.i_agt.drv.set_report_id_verbosity (“ID1”, UVM_HIGH); 这样设置后“ID1INFO”会显示，但“ID2INFO”不会显示。

这个函数同样有其相应的递归调用函数，其调用方式为：env.i_agt.set_report_id_verbosity_hier(“ID1”, UVM_HIGH);

UVM也支持在命令行中设置冗余度阈值：

<sim command> +UVM_VERBOSITY=UVM_HIGH
或者：
<sim command> +UVM_VERBOSITY=HIGH

对不同的component设置不同的冗余度阈值非常有用。在芯片级别验证时重用了不同模块的env。由于个人习惯的不同，通过设置不同env的冗余度级别，可以更好地控制整个芯片验证环境输出信息的质量。

*重载打印信息的严重性

UVM默认有四种信息严重性：UVM_INFO、UVM_WARNING、UVM_ERROR、UVM_FATAL。这四种严重性可以互相重载。如果要把driver中所有的UVM_WARNING显示为UVM_ERROR，可使用如下的函数：

virtual function void connect_phase(uvm_phase phase);
	env.i_agt.drv.set_report_severity_override(UVM_WARNING, UVM_ERROR);
	//env.i_agt.drv.set_report_severity_id_override(UVM_WARNING, "my_driver", UVM_ERROR);
endfunction

重载严重性可以只针对某个component内的某个特定的ID起作用：env.i_agt.drv.set_report_severity_id_override(UVM_WARNING, “my_driver”, UVM_ERROR);

UVM不提供递归的严重性重载函数。严重性重载用的较少，一般只会对某个component内使用，不会
递归的使用。

重载严重性也可在命令行中实现，其调用方式为：

<sim command> +uvm_set_severity=<comp>,<id>,<current severity>,<new severity>
如：<sim command> +uvm_set_severity="uvm_test_top.env.i_agt.drv,my_driver,UVM_WARNING,UVM_ERROR"
//若要设置所有的ID，可以在id处使用_ALL_：
<sim command> +uvm_set_severity="uvm_test_top.env.i_agt.drv,_ALL_,UVM_WARNING,UVM_ERROR"

*UVM_ERROR到达一定数量结束仿真

当uvm_fatal出现时表示出现了致命错误，仿真会马上停止。UVM同样支持UVM_ERROR达到一定数量时结束仿真。如果某个测试用例出现了大量UVM_ERROR，根据这些错误已经可以确定bug所在，再继续仿真的意义不大时就可以结束仿真，而不必等到所有的objection被撤销。

实现这个功能的是set_report_max_quit_count函数，其调用方式为：

function void base_test::build_phase(uvm_phase phase);
	super.build_phase(phase);
	env = my_env::type_id::create("env", this);
	set_report_max_quit_count(5); //把退出阈值设置为5
endfunction

在测试用例中的设置方式与base_test中类似。如果测试用例与base_test中同时设置了，则以测试用例中的设置为准。除了在build_phase之外，也可以在其他phase设置。

get_max_quit_count可用于查询当前的退出阈值。如果返回值为0则表示无论出现多少个UVM_ERROR都不会退出仿真：function int get_max_quit_count();

也可以在命令行中设置退出阈值：第一个参数6表示退出阈值， 而第二个参数NO表示此值是不可以被后面的设置语句重载，其值也可以是YES。

<sim command> +UVM_MAX_QUIT_COUNT=6,NO

*设置计数的目标

当UVM_ERROR达到一定数量时可以自动退出仿真。在计数中是不包含UVM_WARNING的。可通过设置set_report_severity_action函数来把UVM_WARNING加入计数目标：（UVM_INFO也可以这样设置）

virtual function void connect phase(uvm_phase phase);
	set_report_max_quit_count(5);
	env.i_agt.drv.set_report_severity_action(UVM_WARNING, UVM_DISPLAY|UVM_COUNT);
	...
endfunction

set_report_severity_action有相应的递归调用方式：(把env.i_agt及其下所有结点的UVM_WARNING加入到计数目标中)env.i_agt.set_report_severity_action_hier(UVM_WARNING, UVM_DISPLAY| UVM_COUNT);

在默认情况下，UVM_ERROR已经加入了统计计数。如果要把其从统计计数目标中移除：
env.i_agt.drv.set_report_severity_action(UVM_ERROR, UVM_DISPLAY);

除了针对严重性进行计数外，还可以对某个特定的ID进行计数，如对my_drv进行计数：
env.i_agt.drv.set_report_id_action(“my_drv”, UVM_DISPLAY| UVM_COUNT)
这种设置方式同样有其递归调用函数：
env.i_agt.set_report_id_action_hier(“my_drv”, UVM_DISPLAY| UVM_COUNT);

除了分别对严重性和ID进行设置外，UVM还支持把它们联合起来进行设置：
env.i_agt.drv.set_report_severity_id_action(UVM_WARNING, “my_driver”, UVM_DISPLAY| UVM_COUNT);
这种设置方式同样有其递归调用函数：
env.i_agt.set_report_severity_id_action_hier(UVM_WARNING, “my_driver”, UVM_DISPLAY| UVM_COUNT);
UVM也支持在命令行中设置计数目标：

<sim command> +uvm_set_action=<comp>,<id>,<severity>,<action>
//若要针对所有的ID设置，可以使用_ALL_代替ID，如：
<sim command> +uvm_set_action="uvm_test_top.env.i_agt.drv,_ALL_,UVM_WARNING,UVM_DISPLAY|UVM_COUNT"

UVM的断点功能

在程序运行时预先在某语句处设置一断点。当程序执行到此处时停止仿真，进入交互模式从而进行调试。

断点功能需要从仿真器的角度进行设置，不同仿真器的设置方式不同。为了消除这些设置方式的不同，UVM支持内建的断点功能，当执行到断点时自动停止仿真，进入交互模式：

virtual function void connect_phase(uvm_phase phase);
	env.i_agt.drv.set_report_severity_action(UVM_WARNING, UVM_DISPLAY| UVM_STOP);
	//当env.i_agt.drv中出现UVM_WARNING时立即停止仿真，进入交互模式
	…
endfunction

上节介绍的所有函数，只要将其中的UVM_COUNT替换为UVM_STOP，就可实现相应的断点功能。同样的，也可在命令行中设置UVM断点：

<sim command> +uvm_set_action="uvm_test_top.env.i_agt.drv,my_driver,UVM_WARNING,UVM_DISPLAY|UVM_STOP

*将输出信息导入文件中

默认情况下UVM会将UVM_INFO等信息显示在标准输出（终端屏幕）上。各个仿真器提供将显示在标准输出的信息同时输出到一个日志文件中的功能。但这个日志文件混杂了所有的UVM_INFO、 UVM_WARNING、 UVM_ERROR及UVM_FATAL。UVM提供将特定信息输出到特定日志文件的功能：

//将env.i_agt.drv的UVM_INFO输出到info.log，UVM_WARNING输出到warning.log，UVM_ERROR输出到error.log，
//UVM_FATAL输出到fatal.log
UVM_FILE info_log;
	UVM_FILE warning_log;
	UVM_FILE error_log;
	UVM_FILE fatal_log;
	virtual function void connect_phase(uvm_phase phase);
		info_log = $fopen("info.log", "w");
		warning_log = $fopen("warning.log", "w");
		error_log = $fopen("error.log", "w");
		fatal_log = $fopen("fatal.log", "w");
		env.i_agt.drv.set_report_severity_file(UVM_INFO, info_log);
		env.i_agt.drv.set_report_severity_file(UVM_WARNING, warning_log);
		env.i_agt.drv.set_report_severity_file(UVM_ERROR, error_log);
		env.i_agt.drv.set_report_severity_file(UVM_FATAL, fatal_log);
		env.i_agt.drv.set_report_severity_action(UVM_INFO, UVM_DISPLAY| UVM_LOG);
		env.i_agt.drv.set_report_severity_action(UVM_WARNING, UVM_DISPLAY|UVM_LOG);
		env.i_agt.drv.set_report_severity_action(UVM_ERROR, UVM_DISPLAY| UVM_COUNT | UVM_LOG);
		env.i_agt.drv.set_report_severity_action(UVM_FATAL, UVM_DISPLAY|UVM_EXIT | UVM_LOG);
		…
	endfunction

这里用到了set_report_severity_file函数，同样有其递归调用的方式：

//将env.i_agt及其下所有结点的输出信息分类输出到不同的日志文件中
env.i_agt.set_report_severity_file_hier(UVM_INFO, info_log);
env.i_agt.set_report_severity_file_hier(UVM_WARNING, warning_log);
env.i_agt.set_report_severity_file_hier(UVM_ERROR, error_log);
env.i_agt.set_report_severity_file_hier(UVM_FATAL, fatal_log);
env.i_agt.set_report_severity_action_hier(UVM_INFO, UVM_DISPLAY| UVM_LOG);
env.i_agt.set_report_severity_action_hier(UVM_WARNING, UVM_DISPLAY| UVM_LOG);
env.i_agt.set_report_severity_action_hier(UVM_ERROR, UVM_DISPLAY| UVM_COUNT |UVM_LOG);
env.i_agt.set_report_severity_action_hier(UVM_FATAL, UVM_DISPLAY| UVM_EXIT | UVM_LOG);

UVM中还可以根据不同的ID来设置不同的日志文件：

UVM_FILE driver_log;
UVM_FILE drv_log;
virtual function void connect_phase(uvm_phase phase);
	driver_log = $fopen("driver.log", "w");
	drv_log = $fopen("drv.log", "w");
	env.i_agt.drv.set_report_id_file("my_driver", driver_log);
	env.i_agt.drv.set_report_id_file("my_drv", drv_log);
	env.i_agt.drv.set_report_id_action("my_driver", UVM_DISPLAY| UVM_LOG);
	env.i_agt.drv.set_report_id_action("my_drv", UVM_DISPLAY| UVM_LOG);
	…
endfunction
virtual function void final_phase(uvm_phase phase);
	$fclose(driver_log);
	$fclose(drv_log);
endfunction

set_report_id_file函数同样也有递归调用的方式：

//将env.i_agt及其下所有结点的输出信息中ID为my_driver的输出到driver.log中，把ID为my_drv的输出到drv.log中
env.i_agt.set_report_id_file_hier("my_driver", driver_log);
env.i_agt.set_report_id_file_hier("my_drv", drv_log);
env.i_agt.set_report_id_action_hier("my_driver", UVM_DISPLAY| UVM_LOG);
env.i_agt.set_report_id_action_hier("my_drv", UVM_DISPLAY| UVM_LOG);

UVM还可以根据严重性和ID的组合来设置不同的日志文件：

UVM_FILE driver_log;
UVM_FILE drv_log;
virtual function void connect_phase(uvm_phase phase);
	driver_log = $fopen("driver.log", "w");
	drv_log = $fopen("drv.log", "w");
	env.i_agt.drv.set_report_severity_id_file(UVM_WARNING, "my_driver",driver_log);
	env.i_agt.drv.set_report_severity_id_file(UVM_INFO, "my_drv", drv_log);
	env.i_agt.drv.set_report_id_action("my_driver", UVM_DISPLAY| UVM_LOG);
	env.i_agt.drv.set_report_id_action("my_drv", UVM_DISPLAY| UVM_LOG);
	…
endfunction

set_report_severity_id_file同样也有其递归调用的方式：

env.i_agt.set_report_severity_id_file_hier(UVM_WARNING, "my_driver", driver_log);
env.i_agt.set_report_severity_id_file_hier(UVM_INFO, "my_drv", drv_log);
env.i_agt.set_report_id_action_hier("my_driver", UVM_DISPLAY| UVM_LOG);
env.i_agt.set_report_id_action_hier("my_drv", UVM_DISPLAY| UVM_LOG);

*控制打印信息的行为

控制打印信息行为系列函数set_*_action的典型应用。无论是UVM_DISPLAY，UVM_COUNT或
是UVM_LOG，都是UVM内部定义的一种行为。UVM共定义了如下几种行为：

typedef enum
{
	UVM_NO_ACTION = 'b000000, //不做任何操作
	UVM_DISPLAY = 'b000001, //输出到标准输出上
	UVM_LOG = 'b000010, //输出到日志文件中,它能工作的前提是设置好了日志文件
	UVM_COUNT = 'b000100, //作为计数目标
	UVM_EXIT = 'b001000, //直接退出仿真
	UVM_CALL_HOOK = 'b010000, //调用一个回调函数
	UVM_STOP = 'b100000 //停止仿真，进入命令行交互模式
} uvm_action_type;

与field automation机制中定义UVM_ALL_ON类似，这里也把UVM_DISPLAY等定义为一个整数。不同行为有不同的位偏移，所以不同的行为可以使用“或”的方式组合在一起：UVM_DISPLAY| UVM_COUNT | UVM_LOG

默认情况下，UVM设置了如下的行为：

set_severity_action(UVM_INFO, UVM_DISPLAY);
set_severity_action(UVM_WARNING, UVM_DISPLAY);
set_severity_action(UVM_ERROR, UVM_DISPLAY | UVM_COUNT);
set_severity_action(UVM_FATAL, UVM_DISPLAY | UVM_EXIT);

前面通过设置默认的冗余度级别来关闭某些信息的输出，这个功能可通过设置为UVM_NO_ACTION来实现：

virtual function void connect_phase(uvm_phase phase);
	env.i_agt.drv.set_report_severity_action(UVM_INFO, UVM_NO_ACTION);
endfunction

无论原本的冗余度是什么，经过上述设置后，env.i_agt.drv的所有uvm_info信息都不会输出。