[游戏开发]Unity Shader学习-单张纹理

Unity Shader学习-单张纹理

UV坐标

顶点UV坐标的范围一般都在[0,1]的范围内
Unity中的纹理坐标原点在左下角(0,0)

单张纹理

定义纹理属性

要给材质添加纹理，首先需要在Properties中定义一个纹理属性

Properties{
	_MainTex("MainTex",2D) = "white"{}
}

声明变量

然后需要在Pass中声明与属性类型相对应的变量

sampler2D _MainTex;
float4 _MainTex_ST;

除了_MainTex,还需要定义一个_MainTex_ST来存储纹理的缩放(Scale)和平(Translation)移，命名格式必须为纹理名_ST。

定义结构体

struct a2v{
	float4 vertex : POSITION;
	float3 normal : NORMAL;
	//存放纹理坐标
	float4 texcoord : TEXCOORD0;
};
struct v2f{
	float4 pos : POSITION;
	float3 worldNormal : TEXCOORD0;
	float3 worldLightDir : TEXCOORD1;
	//存放纹理坐标的uv
	float2 uv : TEXCOORD2;
};

光照计算

环境光

使用tex2D对纹理进行采样，得到纹素值，然后与定义的属性颜色进行混合，得到反射率,然后与环境光相乘得到环境光

fixed3 albedo = tex2D(_MainTex,i.uv) * _Color.rgb;
fixed3 ambient = UNITY_UNITYLIGHTMODEL_AMBIENT.xyz* albedo;

漫反射

漫反射计算要光源颜色，材质的颜色，同一坐标下的法线和光照方向
材质的颜色由纹理采样得到

fixed3 diffuse = _LightColor0.rgb * albedo.rgb * saturate(dot(worldNormal,worldLightDir));

高光反射

高光反射计算

fixed3 viewDir = normalize(UnityObjectSpaceViewDir(i.worldPos);
fixed3 halfDir = normalize(worldLightDir + viewDir);\
fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(max(0,dot(worldNormal,halfDir)),_Gloss);

最终光照计算

当物体与光源的光照进行计算的时候，由于物体有一个反射率，光照照射到物体上的时候，有一部分光会被物体吸收，与物体的反射率相乘可以得到反射的光线。
环境光和漫反射都会有一部分光线被吸收，而高光反射不会，所以前两者都需要与反射率做乘法运算得出最终的光照结果。
最后每个光照的运算结果相加得出最后的光照效果。
(个人查资料后得到的见解，如果不对欢迎留言，我这边及时改QAQ)

retunr fixed4(ambient + diffuse + specular,1);

完整代码

Shader "Custom/MySingleShader"
{
    Properties
    {
        _Color ("Color", Color) = (1,1,1,1)
        _MainTex ("Main Tex", 2D) = "white" {}
        _Specular ("Specular", Color) = (1,1,1,1)
        _Gloss ("Gloss", Range(8,256)) = 20
    }
    SubShader
    {
        Tags { "RenderType"="Opaque" }
        LOD 200
        Pass{

            Tags { "LightMode"="ForwardBase" }
            LOD 200

            CGPROGRAM
            #include "UnityCG.cginc"
            #include "Lighting.cginc"
            #pragma vertex vert
            #pragma fragment frag

            fixed4 _Color;
            sampler2D _MainTex;
            float4 _MainTex_ST;
            fixed4 _Specular;
            float _Gloss;

            struct a2v{
                fixed4 vertex : POSITION;
                fixed3 normal : NORMAL;
                fixed4 texcoord : TEXCOORD0;
            };
            struct v2f{
                float4 pos : SV_POSITION;
                float3 worldNormal : TEXCOORD0;
                float3 worldPos : TEXCOORD1;
                float2 uv : TEXCOORD2;
            };

            v2f vert(a2v v) : POSITION{
                v2f o;
                o.pos = UnityObjectToClipPos(v.vertex);
                o.worldNormal = UnityObjectToWorldNormal(v.normal);
                o.worldPos = mul(unity_ObjectToWorld,v.vertex).xyz;
                o.uv = TRANSFORM_TEX(v.texcoord,_MainTex).xy;
                return o;
            }
            fixed4 frag(v2f i) : SV_Target{
                fixed3 worldNormal = normalize(i.worldNormal);
                fixed3 worldLightDir =normalize(UnityWorldSpaceLightDir(i.worldPos));
                fixed3 albedo = tex2D(_MainTex,i.uv).rgb * _Color.rgb;

                fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz * albedo;
                fixed3 diffuse = _LightColor0.rgb * albedo *  max(0,dot(worldNormal,worldLightDir));

                fixed3 viewDir =normalize(UnityWorldSpaceViewDir(i.worldPos));
                fixed3 halfDir = normalize(viewDir + worldLightDir);
                fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(max(0,dot(worldNormal,halfDir)),_Gloss);
                return fixed4(ambient + diffuse + specular,1.0);
            }

            ENDCG
        }
    }
    FallBack "Diffuse"
}