[游戏开发]【Godot】通过属性检查器显示对应节点的脚本属性

Godot 3.4.2

脚本代码如下，通过继承这个脚本，重写 get_prop_nodes 方法即可

#============================================================
#	Base Role
#============================================================
#  最基本的角色功能，可对方法进行重写展示对需要修改属性的节点，
#  展示到当前节点的属性检查器中
#============================================================
# @datetime: 2022-1-30 22:50:38
#============================================================
tool
extends KinematicBody2D


var _property_data = {}



#============================================================
#   Set/Get
#============================================================
##  获取要展示的脚本导出的属性的节点
## （继承这个脚本的脚本重写这个节点进行显示
## 返回对应要展示的节点列表）
func get_prop_nodes() -> Array:
	return []



#============================================================
#   内置方法
#============================================================
func _ready():
	_get_property_list()
	for property in _property_data.keys():
		var data = _property_data[property]
		if data.has('node'):
			data['node'].set(data['property'], data['value'])


func _get_property_list():
	var list := []
	for node in get_prop_nodes():	# 在这个列表中添加想要展示的节点的属性的列表
		if node == null:
			printerr("没有这个节点，请确保设置的节点是正确的")
			continue
		var sp_list := (node.get_script() as Script).get_script_property_list() as Array
		var property = ""
		for p_data in sp_list:
			property = "%s/%s" % [node.name , p_data.name]
			# 如果没有这个属性
			if not _property_data.has(property):
				_property_data[property] = {
					"node": node,
					"value": node.get(p_data.name),
				}
			else:
				_property_data[property]["node"] = node
				if not _property_data[property].has("value"):
					_property_data[property]["value"] = node.get(p_data.name)
			_property_data[property]["property"] = p_data.name
			_set(property, _property_data[property]["value"])
			p_data.name = property
		list.append_array(sp_list)
	return list


func _set(property, value):
	# 修改属性时，对对应属性的节点进行修改属性
	if _property_data.has(property):
		var data := _property_data[property] as Dictionary
		if data.has("node"):
			data["node"].set(property, value)
		_property_data[property]["value"] = value
	else:
		_property_data[property] = {}


func _get(property):
	if _property_data.has(property) \
		and _property_data[property].has('value'):
		return _property_data[property]['value']