[游戏开发]【Unity Shader入门精要笔记】02-基础光照

漫反射光照模型（兰伯特模型）

??▲逐顶点漫反射光照，逐像素漫反射光照，半兰伯特光照对比效果

?防止法线和光源方向点乘的结果为负值，使用saturate（x）函数或max（0，n*l）函数，把x截取到[0,1]范围，防止物体被从后面带来的光源照亮。

?1. 逐顶点漫反射光照

?在背光面和向光面交界有一些锯齿，背光面明暗一样。

Shader "Unlit/myDiffusePixelLevelMat"
{
    Properties
    {
        _Diffuse ("Diffuse", Color) = (1, 1, 1, 1)
    }
    SubShader
    {
        Pass
        {
            //指明该Pass的光照模式
            Tags { "LightMode" = "ForwardBase" }
            
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            #include "Lighting.cginc"

            fixed4 _Diffuse;
            struct a2v
            {
                float4 vertex : POSITION;
                float3 normal : NORMAL;
            };
            struct v2f
            {
                float4 pos : SV_POSITION;
                fixed3 color : COLOR;
            };


            //逐顶点的漫反射光照，漫反射部分的计算都在顶点着色器中进行
            v2f vert(a2v v)
            {
                v2f o;
                //把顶点位置从模型空间转换到裁剪空间
                o.pos = UnityObjectToClipPos(v.vertex);
                
                //得到环境光部分
                fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;

                //将法线转换到世界空间
                //使用顶点变换矩阵的逆转置矩阵对法线进行相同变换，_World2Object即为模型矩阵的逆矩阵，同时改变mul参数位置，左乘省去转置步骤。
                fixed3 worldNormal = normalize(mul(v.normal,(float3x3)unity_WorldToObject));

                //得到世界坐标空间的光源方向（单光源且平行光，复杂光不能使用此方法）
                fixed3 worldLight = normalize(_WorldSpaceLightPos0.xyz);
                
                //法线和光源方向点积要求同一空间
                fixed3 diffuse = _LightColor0.rgb * _Diffuse.rgb * saturate(dot(worldNormal,worldLight));
                //saturate（x）函数起到和max（0，n*l）相同的效果，作用是把x截取到[0,1]范围
                o.color = ambient + diffuse;

                return o;
            }

            fixed4 frag(v2f i) : SV_Target
            {
                return fixed4(i.color, 1.0);
            }

            ENDCG
        }
    }
    Fallback "Diffuse"
}

2. 逐像素漫反射光照

可以得到更加平滑的光照效果，背光面明暗一样。

Shader "Unlit/myDiffusePixelLevelMat"
{
    Properties
    {
        _Diffuse ("Diffuse", Color) = (1, 1, 1, 1)
    }
    SubShader
    {
        Pass
        {
            Tags { "LightMode" = "ForwardBase" }
            
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            #include "Lighting.cginc"

            fixed4 _Diffuse;
            struct a2v
            {
                float4 vertex : POSITION;
                float3 normal : NORMAL;
            };
            struct v2f
            {
                float4 pos : SV_POSITION;
                fixed3 worldNormal : TEXCOORD0;
            };
            //逐像素的漫反射光照，漫反射部分的计算都在片元着色器中进行
            //顶点着色器只需要把世界空间下的法线传递给片元着色器即可
            v2f vert(a2v v)
            {
                v2f o;
                //把顶点位置从模型空间转换到裁剪空间
                o.pos = UnityObjectToClipPos(v.vertex);
            
                //将法线部分转换到世界空间
                o.worldNormal = mul(v.normal,(float3x3)unity_WorldToObject);
                return o;
            }

            fixed4 frag(v2f i) : SV_Target
            {
                //得到环境光部分
                fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;

                //得到世界坐标空间下的法线
                fixed3 worldNormal = normalize(i.worldNormal);
                //得到世界坐标空间的光源方向
                fixed3 worldLightDir = normalize(_WorldSpaceLightPos0.xyz);
				//计算漫反射部分
                fixed3 diffuse = _LightColor0.rgb * _Diffuse.rgb * saturate(dot(worldNormal,worldLightDir));
                
                fixed3 color = ambient + diffuse;

                return fixed4(color, 1.0);
            }

            ENDCG
        }
    }
    Fallback "Diffuse"
}

3. 半兰伯特模型

?背光面明暗有变化

?

修改逐像素漫反射光照的一行代码即可：
//计算漫反射部分
fixed3 diffuse = _LightColor0.rgb * _Diffuse.rgb * dot(worldNormal, worldLightDir) * 0.5 + 0.5;

高光反射光照模型

?

▲逐顶点光照，逐像素光照，BlinnPhong光照对比效果?

逐顶点光照:高光部分不平滑

逐像素光照：高光部分平滑

BlinnPhong光照：高光反射部分更大更亮，在实际渲染中常采用此模型。

?1. 逐顶点光照

?

Shader "Unlit/MySpecularVertexLevelMat"
{
    Properties
    {
        _Diffuse("Diffuse",Color) = (1,1,1,1)
        _Specular("Specluar",Color) = (1,1,1,1)  //控制高光反射属性
        _Gloss("Gloss",Range(8.0,256)) = 20     //控制高光区域大小
    }
    SubShader
    {
        
        Pass
        {
            Tags { "LightMode"="ForwardBase" }
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            #include "Lighting.cginc"

            fixed4 _Diffuse;
            fixed4 _Specular;
            float _Gloss;

            struct a2v
            {
                float4 vertex : POSITION;
                float4 normal : NORMAL;
            };

            struct v2f
            {
                float4 pos : SV_POSITION;
                fixed3 color : COLOR;
            };

            v2f vert(a2v v)
            {
                v2f o;
                o.pos = UnityObjectToClipPos(v.vertex);
 
                fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;

                fixed3 worldNormal = normalize(mul(v.normal,(float3x3)unity_WorldToObject));

                fixed3 worldLightDir = normalize(_WorldSpaceLightPos0.xyz);

                fixed3 diffuse = _LightColor0.rgb * _Diffuse.rgb * saturate(dot(worldNormal,worldLightDir));

                //入射光线方向关于表面法线的反射方向
                //由于Cg的reflect函数的入射方向要求是由光源指向交点处，因此我们需要对worldLightDir【取反】后再传给reflect函数
                fixed3 reflectDir = normalize(reflect(-worldLightDir,worldNormal));

                //得到世界空间下的视角方向
                //_WorldSpaceCameraPos.xyz得到世界空间中的摄像机位置，再把顶点位置从模型空间变换到世界空间下，向量相减得到视角方向
                fixed3 viewDir = normalize(_WorldSpaceCameraPos.xyz - mul(unity_ObjectToWorld, v.vertex).xyz);

                //计算高光反射部分
                fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(saturate(dot(viewDir,reflectDir)),_Gloss);
                //pow () 函数用来求 x 的 y 次幂（次方）
                o.color = ambient + diffuse + specular;

                return o;
            }

            fixed4 frag(v2f i) : SV_TARGET
            {
                return fixed4(i.color,1.0);
            }
            ENDCG
        }
    }
    Fallback "Specular"
}

2. 逐像素光照

Shader "Unlit/MySpecularPixelLevelMat"
{
    Properties
    {
        _Diffuse("Diffuse",Color) = (1,1,1,1)
        _Specular("Specluar",Color) = (1,1,1,1)  //控制高光反射属性
        _Gloss("Gloss",Range(8.0,256)) = 20     //控制高光区域大小
    }
    SubShader
    {
        
        Pass
        {
            Tags { "LightMode"="ForwardBase" }
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            #include "Lighting.cginc"

            fixed4 _Diffuse;
            fixed4 _Specular;
            float _Gloss;

            struct a2v
            {
                float4 vertex : POSITION;
                float4 normal : NORMAL;
            };

            struct v2f
            {
                float4 pos : SV_POSITION;
                float3 worldNormal : TEXCOORD0;
                float3 worldPos : TEXCOORD1;
            };
            
            //顶点着色器计算世界空间下的法线方向和顶点坐标，将他们传递给片元着色器
            v2f vert(a2v v)
            {
                v2f o;
                o.pos = UnityObjectToClipPos(v.vertex);
                o.worldNormal = normalize(mul(v.normal,(float3x3)unity_WorldToObject));
                //把顶点位置从模型空间变换到世界空间,用于片元着色器计算视角方向
                o.worldPos = mul(unity_ObjectToWorld,v.vertex).xyz;
                return o;
            }

            fixed4 frag(v2f i) : SV_TARGET
            {
                fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;

                fixed3 worldNormal = normalize(i.worldNormal);
                
                fixed3 worldLightDir = normalize(_WorldSpaceLightPos0.xyz);

                fixed3 diffuse = _LightColor0.rgb * _Diffuse.rgb * saturate(dot(worldNormal,worldLightDir));
                
                fixed3 reflectDir = normalize(reflect(-worldLightDir,worldNormal));

                 fixed3 viewDir = normalize(_WorldSpaceCameraPos.xyz - i.worldPos.xyz);

                 fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(saturate(dot(viewDir,reflectDir)),_Gloss);

                 return fixed4(ambient + diffuse + specular,1.0);
            }
            ENDCG
        }
    }
    Fallback "Specular"
}

3. BlinnPhong模型

修改逐像素光照的一行代码即可：
fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(saturate(dot(worldNormal,normalize(worldLightDir + viewDir))),_Gloss);