[网络协议]Aardio - 【库】sunny网络中间件

本库封装心得：

1、aardio回调函数是被dll用线程启动的，所以在声明回调函数时，不能用 ..raw.tostdcall() ，而是要用 ..thread.tostdcall()。

2、因为线程安全的原因，回调函数不能访问主线程的成员，比如窗口组件。所以在定义回调函数时，给他指定一个owner（比如 winform 或 {form=winform} ），在回调函数中，就可以用 owner 或 owner.form 来访问主窗口对象 winform 了。

3、本库所用sunny.dll不支持内存加载。

4、进行函数功能分类（模块化），以方便调用。

一、SUNNY网络中间件是什么：

Sunny网络中间件 和 Fiddler 模块类似。是可跨平台的网络分析组件。可用于 HTTP / HTTPS / WS / WSS / TCP 网络分析，无内存泄漏，为二次开发量身制作。

Sunny项目主要用于易语言?(其他语言也可使用)目前免费且开源。应dio友需求，我将他封装为aardio库，供有此功能需求的dio友们下载使用。

SDK功能:

1.支持 获取/修改 HTTP/HTTPS/WS/WSS/TCP 发送及返回数据

2.支持 HTTP/HTTPS/WS/WSS 设置全局代理（上游代理）

3.支持 对 HTTP/HTTPS/WS/WSS 指定连接使用指定代理

4.支持 对 HTTP/HTTPS/WS/WSS 链接重定向

5.支持 对 TCP链接进行IP重定向

6.支持 gzip, deflate, br 解码

7.支持 WS/WSS 主动发送数据

8.支持 TCP 主动发送数据

二、运行效果截图：

三、库文件下载：

解压后放到 /lib/godking/ 目录。

chengxu.online??→ aardio资源下载 → sunny.rar

四、库结构：

?五：调用示例：

import win.ui;
import win.ui.ctrl.vlistEx
/*DSG{{*/
var winform = win.form(text="aardio form";right=759;bottom=469;topmost=1)
winform.add(
button={cls="button";text="开始HTTP拦截";left=397;top=394;right=554;bottom=447;db=1;dr=1;z=1};
button2={cls="button";text="停止";left=578;top=394;right=735;bottom=447;db=1;dr=1;z=2};
button3={cls="button";text="打开ws测试网站";left=216;top=394;right=373;bottom=447;db=1;dl=1;z=4};
button4={cls="button";text="打开wss测试网站";left=35;top=394;right=192;bottom=447;db=1;dl=1;z=8};
rb1={cls="radiobutton";text="替换图片";left=105;top=356;right=258;bottom=384;checked=1;db=1;dl=1;font=LOGFONT(h=-16);z=5};
rb2={cls="radiobutton";text="阻止图片";left=281;top=356;right=434;bottom=384;db=1;dl=1;dr=1;font=LOGFONT(h=-16);z=6};
rb3={cls="radiobutton";text="图片放行";left=451;top=356;right=604;bottom=384;db=1;dr=1;font=LOGFONT(h=-16);z=7};
vlist={cls="win.ui.ctrl.vlistEx";text="自定义控件";left=10;top=8;right=752;bottom=350;db=1;dl=1;dr=1;dt=1;z=3}
)
/*}}*/

winform.vlist.setColumns({"序号","协议类型","消息类型","传输模式","url"},{40,70,120,70,-1});

import godking.sunny
var sunny=godking.sunny()
sunny.callback_http = function(winform,id,msgid,msgtype,mod,url,pid,notice,err){
	// 注意：1、回调函数为线程函数；2、要重新引用godking.sunny
	import godking.sunny
	// 将部分内容写入窗口虚表中
	winform.vlist.addRow("[@rowindex]","http/s",godking.sunny.msgType.getName(msgtype),mod,url)
	winform.vlist.ensureVisible(winform.vlist.count)
	// 将图片请求进行替换
	if msgtype==godking.sunny.msgType.http_request and !winform.rb3.checked {
		var request = godking.sunny.httpRequest(msgid);
		var t = request.getHeader("Content-Type")
		import string
        if ..string.find(url,"@@.jpg") or ..string.find(url,"@@.jpeg") or ..string.find(url,"@@.png"){
            if winform.rb1.checked request.setUrl("http://chengxu.online/images/banner.gif");
            if winform.rb2.checked request.setUrl("");
        }
	}
	// 过滤掉图片的正文消息
	if msgtype==godking.sunny.msgType.http_response and notice {
		var request = godking.sunny.httpResponse(msgid);
		var t = request.getHeader("Content-Type")
		import string
        if ..string.find(t,"@image/",1){
			return true; 
        }
	}
}

sunny.callback_websocket = function(winform,id,msgid,msgtype,mod,url,pid){
	// 注意：1、回调函数为线程函数；2、要重新引用godking.sunny
	import godking.sunny
	// 将部分内容写入窗口虚表中
	winform.vlist.addRow("[@rowindex]","websocket",godking.sunny.msgType.getName(msgtype),mod,url)
	winform.vlist.ensureVisible(winform.vlist.count)
	// 拦截发送数据
	if msgtype==godking.sunny.msgType.ws_send or msgtype==godking.sunny.msgType.wss_send {
		var ws = godking.sunny.webSocket(msgid);
		var t = ws.getBodyText();
		winform.vlist.addRow("[@rowindex]","websocket","发送数据",mod,t)
		winform.vlist.ensureVisible(winform.vlist.count)
		t = t++"（已修改）"
		ws.setBody(t)
   	}
   	// 拦截接收数据
	if msgtype==godking.sunny.msgType.ws_received or msgtype==godking.sunny.msgType.wss_received {
 		var ws = godking.sunny.webSocket(msgid);
		var t = ws.getBodyText();
		winform.vlist.addRow("[@rowindex]","websocket","接收数据",mod,t)
		winform.vlist.ensureVisible(winform.vlist.count)
  	}
}	

winform.button.oncommand = function(id,event){
	if sunny.start(2021/*代理端口*/,true/*过滤正文*/,true/*全局代理*/,true/*禁止压缩*/,winform/*传递窗口*/) {
		..win.msgbox("已开启！",,,winform.hwnd);
	} else {
		..win.msgbox("开启失败！",,,winform.hwnd);
	}
}

winform.button2.oncommand = function(id,event){
	sunny.stop();
	..win.msgbox("已停止！",,,winform.hwnd);
}

winform.button3.oncommand = function(id,event){
	import process
	process.execute("http://coolaf.com/tool/chattest")
}

winform.button4.oncommand = function(id,event){
	import process
	process.execute("https://www.idcd.com/tool/socket")	
}

winform.show();
win.loopMessage();